Neste artigo você aprenderá como calcular o bimestre no Excel utilizando fórmulas passo-a-passo.
1. Introdução Cálculo de Bimestre no Excel
As datas estão entre os tipos de dados mais especiais, sobremaneira quando falamos em análises. É notório o poder que as análises temporais apresentam e um agrupamento de datas útil são os bimestres, embora ainda menos usados do que bimestre.
Conhecidamente, os bimestres são períodos de 2 meses, sendo os mais notáveis (dentro de um mesmo ano):
- o 1º, de janeiro a fevereiro
- o 2º, de março a abril
- o 3º, de maio a junho
- o 4º, de julho a agosto
- o 5º, de setembro a outubro
- o 6º, de novembro a dezembro
Diversos negócios avaliam performance e resultados bimestralmente. Além disso, pode ser útil retornamos o bimestre de datas com fórmulas em situações diversas. Este é o objetivo deste artigo.
2. Fórmulas para o cálculo do bimestre da data
A seguir veremos 10 fórmulas alternativas que podem ser utilizadas para calcularmos os bimestres baseados em datas. A grande maioria delas está fundamentada inicialmente na obtenção do número do mês presente nas datas (indo de 1 a 12). Este número é retornado através da função MÊS. As 2 últimas soluções utilizam a função TEXTO, em vez de MÊS.
a) Utilizando as funções INT e MÊS
A função INT retorna apenas a parte inteira de um número, uma vez que arredonda o número para baixo, até o inteiro mais próximo. A fórmula da imagem a seguir usa INT para retornar a parte inteira do número resultante da divisão da soma do número do mês com 1, por 2.
A fórmula inserida foi =INT((MÊS(B3)+1)/2). Desta forma, quando o mês é abril, por exemplo, a função MÊS retorna 4, que resulta em 5 ao ser somado com 1. Este resultado dividido por 2 resulta em 2,5. Com isso, a função INT retorna 2, indicando que abril pertence ao segundo bimestre.
b) Utilizando as funções ARREDONDAR.PARA.CIMA e MÊS para Calcular Bimestre no Excel
A nossa próxima fórmula divide o número do mês por 2, arredondando em seguida para cima, até o próximo inteiro. Quando os meses são os últimos dos bimestres, ou seja, múltiplos de 2 (fevereiro, abril, junho, agosto, outubro e dezembro), temos resultados inteiros e o arredondamento não os altera. Caso contrário, teremos resultados como 4,5 (primeiro exemplo da imagem a seguir, no caso de setembro), em que MÊS retorna 9, que dividido por 2 resulta em 4,5. Neste caso, o arredondamento para cima resulta em 5, que é o próximo inteiro.
A fórmula inserida foi =ARREDONDAR.PARA.CIMA(MÊS(B3)/2;0).
c) Utilizando as funções SE e MÊS
Com a função SE podemos verificar o número do mês para obter os resultados. A fórmula da imagem a seguir avaliar se o número do mês é superior a 10 (sendo possível então apenas 11 e 12), o que implica na data pertencer ao 6º bimestre. Não sendo maior que 10, a segunda função SE avalia se o número do mês é superior a 8, o que implica na data ser pertencente ao 5º bimestre (já que o mês será 9 ou 10). A última função SE avalia se o número mês é superior a 2, o que implica na data ser pertencente ao 2º bimestre (já que o mês será 3 ou 4). Por fim, por eliminação, o mês só poderá ser menor ou igual a 2, o que implica na data ser com certeza pertencente ao 1º bimestre.
A fórmula inserida foi =SE(MÊS(B3)>10;6;SE(MÊS(B3)>8;5;SE(MÊS(B3)>6;4;SE(MÊS(B3)>4;3;SE(MÊS(B3)>2;2;1))))).
d) Utilizando as funções SES e MÊS
A função SES aqui empregada toma como base exatamente o mesmo raciocínio da fórmula do item anterior na qual empregamos a função SE. Basicamente, muda-se apenas a escrita, mas mantém-se a lógica.
A fórmula inserida foi =SES(MÊS(B3)>10;6;MÊS(B3)>8;5;MÊS(B3)>6;4;MÊS(B3)>4;3;MÊS(B3)>2;2;MÊS(B3)>0;1).
e) Utilizando as funções PROCV e MÊS
A fórmula deste item utiliza PROCV com correspondência aproximada utilizando o conceito de faixas para enquadrar o número do mês em um intervalo e assim buscar o resultado, indicando o bimestre correspondente à data.
A fórmula inserida foi =PROCV(MÊS(B3);{1\1;3\2;5\3;7\4;9\5;11\6};2;1).
f) Utilizando as funções ÍNDICE, CORRESP e MÊS para Calcular Bimestre no Excel
A fórmula deste tópico é basicamente a conversão da fórmula anterior, porém utilizando ÍNDICE e CORRESP. Mantendo o raciocínio, o último argumento de CORRESP também é 1, e, assim como PROCV (item anterior), faz a busca com correspondência aproximada.
A fórmula inserida foi =ÍNDICE({1;2;3;4;5;6};CORRESP(MÊS(B3);{1;3;5;7;9;11};1)).
g) Utilizando as funções ESCOLHER e MÊS
A função ESCOLHER é aqui empregada para escolher um resultado com base em 12 valores possíveis (meses de 1 a 12). Após o primeiro argumento de ESCOLHER, que é o resultado da função MÊS (valor inteiro variável entre 1 e 12), temos 12 possíveis resultados correspondentes.
A fórmula inserida foi =ESCOLHER(MÊS(B3);1;1;2;2;3;3;4;4;5;5;6;6).
h) Utilizando as funções PARÂMETRO e MÊS
A função PARÂMETRO trabalha de forma similar à função ESCOLHER. A diferença é que após o primeiro argumento, que possui a expressão a ser avaliada (e que resulta em um número inteiro de 1 a 12), a função PARÂMETRO apresenta os 12 possíveis resultados oriundos da função MÊS com as suas devidas correspondências, sempre aos pares.
A fórmula inserida foi =PARÂMETRO(MÊS(B3);1;1;2;1;3;2;4;2;5;3;6;3;7;4;8;4;9;5;10;5;11;6;12;6).
i) Utilizando as funções PROCV e TEXTO
Esta solução já usa a função TEXTO, e não MÊS. A função TEXTO é utilizada para obter o nome dos meses abreviados. Estes nomes são utilizados para pesquisar na matriz o bimestre já disponibilizado correspondente a cada mês.
A fórmula inserida foi = =PROCV(TEXTO(B3;”mmm”);{“jan”\1;”fev”\1;”mar”\2;”abr”\2;”mai”\3;”jun”\3;”jul”\4;”ago”\4;”set”\5;”out”\5;”nov”\6;”dez”\6};2;0).
j) Utilizando as funções ÍNDICE, CORRESP e TEXTO
A fórmula deste tópico segue o mesmo conceito da fórmula anterior, porém utiliza ÍNDICE e CORRESP.
A fórmula inserida foi = =ÍNDICE({1;1;2;2;3;3;4;4;5;5;6;6};CORRESP(TEXTO(B3;”mmm”);{“jan”;”fev”;”mar”;”abr”;”mai”;”jun”;”jul”;”ago”;”set”;”out”;”nov”;”dez”};0)).
Download Planilha Calcular e Extrair Bimestre de Datas no Excel
Clique no botão abaixo para realizar o download do arquivo de exemplo:
