Fórmula Excel Números que Mais se Repetem

Neste vídeo você aprenderá como criar uma fórmula Excel para listar os números que mais se repetem e a quantidade de vezes que os números se repetem.

No nosso exemplo usamos a base histórica de sorteios do

Lista com Números Mais Sorteados na Megasena

A megasena tem sorteios desde 11/03/1996, e ao total foram 2.661 sorteios até o dia 28/11/2023.

Na base histórica temos também as datas, prêmio de alguns e a quantidade de apostas.

Cabeçalho da Fórmula de Números Mais Repetidos no Excel

Para a nossa fórmula criamos um parâmetro no campo Qtde., nele temos a quantidade de números que mais repetem que desejamos retornar.

O cabeçalho irá retornar a sequência e também a quantidade de sequência de itens.

A fórmula mais utilizada é: =EMPILHARH(SEQUÊNCIA(1;O4)&".º";"Qt "&SEQUÊNCIA(1;O4)&".º").

Além disso temos a quantidade de números que mais se repetem:

A fórmula que utilizamos para mostrar os números mais repetidos no Excel foi:

=LET(intervalo;$D$7:$I$2667;
dados;ESCOLHERLINS(ÚNICO(CLASSIFICAR(EMPILHARH(PARACOL(intervalo);CONT.SES(intervalo;
PARACOL(intervalo)));2;-1));SEQUÊNCIA($O$4));
TRANSPOR(EMPILHARV(ESCOLHERCOLS(dados;1);ESCOLHERCOLS(dados;2))))

Para usar em outra planliha apenas altere o intervalo D7:I2667 e altere também o intervalo O4 na fórmula, nela temos a quantidade de números que se repetem.

Mudando estes parâmetros a fórmula já calcula na hora.

Como resultado da aplicação da fórmula de cabeçalho e na fórmula de números mais repetidos temos a imagem acima, e também a abaixo:

Na primeira parte mostra quais os números que mais se repetem e na segunda parte a quantidade de repetições que tivemos de cada número.

Aplicação da Fórmula em Uma Lista Com Números Repetidos no Excel

Abaixo temos uma lista com vários números na horizontal, veja que temos números que se repetem nas posições de 1 à 25 em cada linha:

Para isso aplicamos a seguinte fórmula e arrastamos para cada uma das linhas da tabela:

=LET(intervalo;A9:Y9;
dados;ESCOLHERLINS(ÚNICO(CLASSIFICAR(EMPILHARH(PARACOL(intervalo);CONT.SES(intervalo;
PARACOL(intervalo)));2;-1));SEQUÊNCIA($AB$4));
TRANSPOR(EMPILHARV(ESCOLHERCOLS(dados;1);ESCOLHERCOLS(dados;2))))

Como resultado temos a tabela acima, com os 3 números mais repetidos por linha e também a quantidade de vezes que os números se repetem.

A fórmula pode ser aplicada na horizontal, vertical ou ainda em matrizes com linhas e colunas, uma matriz.

Download Planilha Fórmula Excel Números que Mais se Repetem

Clique no botão abaixo para realizar o  download do arquivo de exemplo: