Soma com Filtro de Datas no Excel

Neste artigo veja como realizar soma com filtro de datas no Excel passo-a-passo com download de planilha exemplo.

1. Introdução

Especialmente para resumos e relatórios temos a necessidade de demonstrações temporais. Totalizar dados baseados em datas pode ser realizado de diversas formas no Excel: Power Query, DAX, VBA, fórmulas etc.

O foco deste artigo é demonstrar como obter somas para resumos e relatórios a partir de fórmulas e fundamentadas em intervalos/períodos de datas.

Neste contexto, as datas constam como critérios/filtros, podendo, obviamente, haver outros. Neste artigo são propostos alguns cases com fórmulas distintas baseadas em funções para a obtenção do mesmo resultado.

A imagem seguinte é um recorte demonstrativo dos dados utilizados.

P.S: a base de dados está estruturada em formato de tabela, chamada tabDados, com campos Data, Produtos, Pgto e Valor. Estes termos – nome da tabela e de seus campos – serão usados nas fórmulas.

2. Criando fórmulas para totalizar por período de datas

As fórmulas propostas, a priori, serão baseadas na função SOMASES. No entanto, de forma alternativa, serão também listadas fórmulas equivalentes usando outras funções, mas que entregam o mesmo resultado.

2.1 Datas informadas na fórmula

Com base nos dados do recorte ilustrado na imagem anterior, qual a soma geral (ou seja: envolvendo todos os Produtos e Pgtos) do período de 25/05/2022 a 05/10/2024?

Temos um caso em que a soma vai de uma certa data até outra. A soma deve contemplar todos os valores a partir da data inicial e não deve extrapolar a data final, tendo a data final como limite (superior). Em outras palavras: a soma deve envolver todas as datas maiores ou iguais (>=) à data inicial e, simultaneamente (interseção), deve envolver todas as datas menores ou iguais (<=) à data final.

Estas notações comparativas podem ser informadas diretamente na fórmula, de forma constante, inteiramente entre aspas. A notação a partir da data 25/05/2022 é então assim escrita: “>=25/05/2022”. A notação até a data 05/10/2024 é então assim escrita: “<=05/10/2024”.

A fórmula obtida então é: =SOMASES(tabDados[Valor];tabDados[Data];">=25/05/2022";tabDados[Data];"<=05/10/2024").

Fórmulas alternativas:

• =SOMA(((tabDados[Data]>=0+"25/05/2022")*(tabDados[Data]<=0+"5/10/2024"))*tabDados[Valor])
• =SOMA(SE(tabDados[Data]>=0+"25/05/2022";SE(tabDados[Data]<=0+"5/10/2024";tabDados[Valor])))
• =SOMA(FILTRO(tabDados[Valor];((tabDados[Data]>=0+"25/05/2022")*(tabDados[Data]<=0+"5/10/2024"))))

P.S: o zero somado ao texto das datas converte o tipo texto destas em número.

As fórmulas listadas são usadas para tomar como base um intervalo de ... até. Caso a ideia seja apenas ter uma data de início, somando esta e todas as seguintes sem uma data final, ou ter uma data final, somando esta e todas as anteriores sem uma data inicial, as fórmulas ficariam então simplificadas.

Para o caso de haver apenas data inicial, as fórmulas ficariam assim adaptadas, visto que não temos um “ponto de parada”:

• =SOMASES(tabDados[Valor];tabDados[Data];">=25/05/2022")
• =SOMA((tabDados[Data]>=0+"25/05/2022")*tabDados[Valor])
• =SOMA(SE(tabDados[Data]>=0+"25/05/2022"; tabDados[Valor]))
• =SOMA(FILTRO(tabDados[Valor];(tabDados[Data]>=0+"25/05/2022")))

Para o caso de haver apenas data final, as fórmulas ficariam assim adaptadas, visto que não temos um “ponto de partida”:

• =SOMASES(tabDados[Valor];tabDados[Data];"<=05/10/2024")
• =SOMA((tabDados[Data]<=0+"05/10/2024")*tabDados[Valor])
• =SOMA(SE(tabDados[Data]<=0+"05/10/2024";tabDados[Valor]))
• =SOMA(FILTRO(tabDados[Valor];(tabDados[Data]<=0+"05/10/2024")))

2.2 Datas informadas em células - Soma com Filtro de Datas no Excel

Agora vamos informar as datas em células. Esta opção é mais interessante pois permite mais controle e, caso optemos por customizar o período, torna-se simples fazê-lo sem necessidade de alteração da fórmula, o que no caso anterior é inevitável.

Em nosso caso a data inicial e a data final estão em H2 e H3, respectivamente. Dado o contexto, a fórmula proposta é: =SOMASES(tabDados[Valor];tabDados[Data];">="&H2;tabDados[Data];"<="&H3). Note que os argumentos da função SOMASES os operadores de comparação (>= e <=) ficam entre aspas e ligados às datas (H2 e H3) por meio do operador de concatenação (&).

Fórmulas alternativas:

• =SOMA(((tabDados[Data]>=H2)*(tabDados[Data]<=H3))*tabDados[Valor])
• =SOMA(SE(tabDados[Data]>=H2;SE(tabDados[Data]<=H3;tabDados[Valor])))
• =SOMA(FILTRO(tabDados[Valor];((tabDados[Data]>=H2)*(tabDados[Data]<=H3))))

As fórmulas listadas são usadas para tomar como base um intervalo de ... até. Caso a ideia seja apenas ter uma data de início, somando todas as seguintes sem data final, ou ter uma data final, somando todas as anteriores sem data inicial, as fórmulas ficariam então simplificadas.

Para o caso de haver apenas data inicial, as fórmulas ficariam assim adaptadas, visto que não temos um “ponto de parada”:

• =SOMASES(tabDados[Valor];tabDados[Data]; ">="&H2)
• =SOMA((tabDados[Data]>=H2)*tabDados[Valor])
• =SOMA(SE(tabDados[Data]>=H2; tabDados[Valor]))
• =SOMA(FILTRO(tabDados[Valor];(tabDados[Data]>=H2)))

Para o caso de haver apenas data final, as fórmulas ficariam assim adaptadas, visto que não temos um “ponto de partida”:

• =SOMASES(tabDados[Valor];tabDados[Data]; "<="&H3)
• =SOMA((tabDados[Data]<=H3)*tabDados[Valor])
• =SOMA(SE(tabDados[Data]<=H3; tabDados[Valor]))
• =SOMA(FILTRO(tabDados[Valor];(tabDados[Data]<=H3)))

P.S: caso o período seja de apenas uma data, ou seja, início e fim sejam a mesma data, as fórmulas expostas neste artigo ficariam bem mais simplificadas. A seguir todas as fórmulas são reescritas expondo como ficaria a soma caso sejam considerados apenas valores referentes ao dia único de 25/05/2022 (inserida em H2):

• =SOMA((tabDados[Data]=0+"25/05/2022")*tabDados[Valor])
• =SOMA((tabDados[Data]=H2)*tabDados[Valor])
• =SOMA(FILTRO(tabDados[Valor];tabDados[Data]=0+"25/05/2022"))
• =SOMA(FILTRO(tabDados[Valor];tabDados[Data]=H2))
• =SOMA(SE(tabDados[Data]=0+"25/05/2022";tabDados[Valor]))
• =SOMA(SE(tabDados[Data]=H2;tabDados[Valor]))
• =SOMASES(tabDados[Valor];tabDados[Data];"25/05/2022")
• =SOMASES(tabDados[Valor];tabDados[Data];H2)

Download Planilha Soma com Filtro de Datas no Excel

Clique no botão abaixo para realizar o  download do arquivo de exemplo: