Função Pivotar com Várias Colunas de Cálculo

Neste artigo você aprenderá como usar a função Pivotar com Várias Colunas de Cálculo no Excel.

Função Pivotar Excel

A função PIVOTAR do Excel é usada para transformar dados organizados em linhas em colunas, ou vice-versa. Esse processo é conhecido como transposição de dados ou pivotagem, e é extremamente útil quando você precisa reorganizar uma tabela para facilitar análises ou relatórios.

✅ Principais usos da função PIVOTAR:

• Converter linhas em colunas de forma dinâmica.
• Criar relatórios organizados por categorias (como nome de produto, mês, região).
• Evitar o uso de tabelas dinâmicas tradicionais em certas situações, mantendo a flexibilidade com fórmulas.
• Permitir mais controle e personalização na disposição dos dados diretamente em fórmulas.

Esta é a sintaxe básica:

=PIVOTAR(matriz_dados; nomes_linha; nomes_coluna; valores; [função_agregação])

Parâmetro	Obrigatório	Descrição
matriz_dados	✅ Sim	É a tabela de origem que será transformada. Pode ser um intervalo de células, uma tabela ou uma matriz dinâmica. Ex: A1:C100.
nomes_linha	✅ Sim	Coluna(s) da matriz original que devem se tornar as linhas da nova tabela. Pode ser uma única coluna ou uma combinação (matriz). Ex: A:A.
nomes_coluna	✅ Sim	Coluna da matriz original que será transformada em colunas da nova tabela. Ex: B:B.
valores	✅ Sim	Coluna que contém os valores numéricos a serem exibidos na nova tabela. Ex: C:C.
função_agregação	❌ Opcional	Especifica como agregar os dados se houver repetições. As funções possíveis são: "SOMA", "MÉDIA", "MÍNIMO", "MÁXIMO", "CONT.VALORES" etc. Se omitido, o padrão é "SOMA".

💡 Observações:

• A função PIVOTAR é diferente da Tabela Dinâmica (Pivot Table), pois é uma função de fórmula, enquanto a Tabela Dinâmica é uma ferramenta visual.
• Pode ser combinada com ORDENAR, UNIQUE, FILTRO e outras funções de matriz dinâmica para criar relatórios poderosos.
• Está disponível apenas no Excel com suporte a matrizes dinâmicas (Microsoft 365).

Tabela de Teste Pivotar Excel

A tabela que usamos para teste é um cadastro de funcionários conforme temos abaixo.

Função Pivotar Excel com Várias Colunas

A função Pivotar trabalha com apenas uma coluna de agregação por padrão.

Por exemplo, podemos realizar uma agregação de SOMA, MÉDIA, CONTAGEM,...

Mas com a utilização de algumas funções de matrizes dinâmicas podemos aplicar mais de um cálculo.

Abaixo temos a aplicação da seguinte fórmula:

=LET(
            ORIGEM;ESCOLHERCOLS(tFuncionarios;I5);
            CABECALHO;{"LINHA"\"MÉDIA"\"QTDE"\"SOMA"};
            LINHAS;ESCOLHERCOLS(PIVOTAR(ORIGEM;;tFuncionarios[Salário atual];SOMA);1);
            MEDIA1;ESCOLHERCOLS(PIVOTAR(ORIGEM;;tFuncionarios[Salário atual];MÉDIA);2);
            QTDE1;ESCOLHERCOLS(PIVOTAR(ORIGEM;;tFuncionarios[Salário atual];CONT.VALORES);2);
            SOMA1;ESCOLHERCOLS(PIVOTAR(ORIGEM;;tFuncionarios[Salário atual];SOMA);2);
            DADOS;EMPILHARH(LINHAS;MEDIA1;QTDE1;SOMA1);
            TOTAL1;ESCOLHERLINS(DADOS;LINS(DADOS));
            DADOSCLASSIFICAR;ESCOLHERLINS(DADOS;SEQUÊNCIA(LINS(DADOS)-1));
            EMPILHARV(CABECALHO;DADOSCLASSIFICAR;TOTAL1))

Na fórmula acima aplicamos o uso da função LET para separar por partes os cálculos usando as funções ESCOLHERCOLS e PIVOTAR para que sejam separadas as colunas de agregação calculando várias vezes a função pivotar.

Após isso usamos o EMPILHARH para empilhar os dados na horizontal e adicionar as colunas.

E para adicionar as linhas de total e de cabeçalho usamos a função EMPILHARV, para empilhar as linhas na vertical.

No vídeo ao topo do artigo você tem passo-a-passo como criar e no botão abaixo tem o download gratuito da planilha pronta da função Pivotar do Excel com várias colunas de cálculo.

Download Planilha Pivotar com Várias Colunas de Cálculo

Realize o download da planilha de HistóricodeAções neste botão abaixo. Basta se inscrever na nossa newsletter gratuita para o download automático.