Como Exibir o Datas como Trimestre no Excel

Leia neste artigo como configurar data como trimestre no Excel.

Como Configurar Datas como Trimestre no Excel

As datas estão entre os tipos de dados mais especiais, sobremaneira quando falamos em análises. É notório o poder que as análises temporais apresentam e um agrupamento de datas bastante útil e explorado são os trimestres.

Conhecidamente, os trimestres são períodos de 3 meses, sendo os trimestres notáveis: o 1º, de janeiro a março, o 2º, de abril a junho, o 3º, de julho a setembro e o 4º, de outubro a dezembro.

Diversos negócios avaliam performance e resultados trimestralmente. No Excel, nativamente em tabelas dinâmicas, temos a opção de resumir os dados por trimestres nos agrupamentos disponíveis para as datas, como pode ser visualizado na tabela dinâmica a seguir, na qual também resumimos mensalmente.

trimestre data excel 1

Rotineiramente resumimos dados trimestralmente em tabelas dinâmicas, inclusive utilizando o Power Pivot e tabelas de dimensões de calendários.

Além disso, pode ser útil retornamos o trimestre de datas com fórmulas em situações diversas. Este é o objetivo deste artigo.

2. Fórmulas para o Cálculo de Datas como Trimestre no Excel

A seguir veremos 10 fórmulas alternativas de como configurar data como trimestre no Excel e que podem ser utilizadas para calcularmos os trimestres baseados em datas. A grande maioria delas está fundamentada inicialmente na obtenção do número do mês presente nas datas (indo de 1 a 12). Este número é retornado através da função MÊS. As 2 últimas soluções utilizam a função TEXTO, em vez de MÊS.

a) Utilizando as funções INT e MÊS

A função INT retorna apenas a parte inteira de um número, uma vez que arredonda o número para baixo, até o inteiro mais próximo. A fórmula da imagem a seguir usa INT para retornar a parte inteira do número resultante da divisão da soma do número do mês com 2, por 3.

trimestre data excel 2

A fórmula inserida foi =INT((MÊS(B3)+2)/3). Desta forma, quando o mês é maio, por exemplo, a função MÊS retorna 5, que resulta em 2 ao ser somado com 7. Este resultado dividido por 3 resulta em 2,6666667. Com isso, a função INT retorna 2, indicando que maio pertence ao segundo trimestre.

Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=89.

b) Utilizando as funções ARREDONDAR.PARA.CIMA e MÊS

A nossa próxima fórmula que converte data em trimestre divide o número do mês por 3, arredondando em seguida para cima, até o próximo inteiro. Quando os meses são os últimos dos trimestres, ou seja, múltiplos de 3 (março, junho, setembro e dezembro), temos resultados inteiros e o arredondamento não os altera. Caso contrário, teremos resultados como 3,3333333 (no caso de outubro, por exemplo), em que MÊS retorna 10, que dividido por 3 resulta em 3,3333333. Neste caso, o arredondamento para cima resulta em 4, que é o próximo inteiro.

trimestre data excel 3

A fórmula para converter datas em Trimestre no Excel foi =ARREDONDAR.PARA.CIMA(MÊS(B3)/3;0). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=170.

c) Utilizando as funções SE e MÊS

Com a função SE podemos verificar o número do mês para obter os resultados. A fórmula da imagem a seguir avaliar se o número do mês é superior a 9, o que implica na data pertencer ao 4º trimestre. Não sendo maior que 9, a segunda função SE avalia se o número do mês é superior a 6, o que implica na data ser pertencente ao 3º trimestre (já que o mês será 7, 8 ou 9). A última função SE avalia se o número mês é superior a 3, o que implica na data ser pertencente ao 2º trimestre (já que o mês será 4, 5 ou 6). Por fim, por eliminação, o mês só poderá ser menor ou igual a 3, o que implica na data ser com certeza pertencente ao 1º trimestre.

trimestre data excel 4

A fórmula inserida foi =SE(MÊS(B3)>9;4;SE(MÊS(B3)>6;3;SE(MÊS(B3)>3;2;1))). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=259.

d) Utilizando as funções SES e MÊS

A função SES aqui empregada toma como base exatamente o mesmo raciocínio da fórmula do item anterior na qual empregamos a função SE. Basicamente, muda-se apenas a escrita, mas mantém-se a lógica.

trimestre data excel 5

A fórmula inserida foi =SES(MÊS(B3)>9;4;MÊS(B3)>6;3;MÊS(B3)>3;2;MÊS(B3)>0;1). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=321.

e) Utilizando as funções PROCV e MÊS

A fórmula deste item utiliza PROCV com correspondência aproximada utilizando o conceito de faixas para enquadrar o número do mês em um intervalo e assim buscar o resultado, indicando o trimestre correspondente à data.

trimestre data excel 6

A fórmula inserida foi =PROCV(MÊS(B3);{1\1;4\2;7\3;10\4};2;1). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=381.

f) Utilizando as funções ÍNDICE, CORRESP e MÊS

A fórmula deste tópico é basicamente a conversão da fórmula anterior, porém utilizando ÍNDICE e CORRESP. Mantendo o raciocínio, o último argumento de CORRESP também é 1, e, assim como PROCV (item anterior), faz a busca com correspondência aproximada.

trimestre data excel 7

A fórmula inserida foi =ÍNDICE({1;2;3;4};CORRESP(MÊS(B3);{1;4;7;10};1)). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=518.

g) Utilizando as funções ESCOLHER e MÊS

A função ESCOLHER é aqui empregada para escolher um resultado com base em 12 valores possíveis (meses de 1 a 12). Após o primeiro argumento de ESCOLHER, que é o resultado da função MÊS (valor inteiro variável entre 1 e 12), temos 12 possíveis resultados correspondentes.

trimestre data excel 8

A fórmula inserida foi =ESCOLHER(MÊS(B3);1;1;1;2;2;2;3;3;3;4;4;4). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=607.

h) Utilizando as funções PARÂMETRO e MÊS

A função PARÂMETRO trabalha de forma similar à função ESCOLHER. A diferença é que após o primeiro argumento, que possui a expressão a ser avaliada (e que resulta em um número inteiro de 1 a 12), a função PARÂMETRO apresenta os 12 possíveis resultados oriundos da função MÊS com as suas devidas correspondências, sempre aos pares.

trimestre data excel 9

A fórmula inserida foi =PARÂMETRO(MÊS(B3);1;1;2;1;3;1;4;2;5;2;6;2;7;3;8;3;9;3;10;4;11;4;12;4). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=685.

i) Utilizando as funções PROCV e TEXTO

Esta solução já usa a função TEXTO, e não MÊS. A função TEXTO é utilizada para obter o nome dos meses abreviados. Estes nomes são utilizados para pesquisar na matriz o trimestre já disponibilizado correspondente a cada mês.

trimestre data excel 10

A fórmula inserida foi =PROCV(TEXTO(B3;”mmm”);{“jan”\1;”fev”\1;”mar”\1;”abr”\2;”mai”\2;”jun”\2;”jul”\3;”ago”\3;”set”\3;”out”\4;”nov”\4;”dez”\4};2;0). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=806.

j) Utilizando as funções ÍNDICE, CORRESP e TEXTO

A fórmula deste tópico segue o mesmo conceito da fórmula anterior, porém utiliza ÍNDICE e CORRESP.

A fórmula inserida foi =ÍNDICE({1;1;1;2;2;2;3;3;3;4;4;4};CORRESP(TEXTO(B3;”mmm”);{“jan”;”fev”;”mar”;”abr”;”mai”;”jun”;”jul”;”ago”;”set”;”out”;”nov”;”dez”};0)). Acompanhe a explicação desta fórmula acessando: https://youtu.be/a-9QUyEU6N8?t=900.

Download Planilha Data como Trimestre

Clique no botão abaixo para realizar o  download da planilha de trimestre de datas Excel, com exemplo de dados:

Baixe a planilha


Jardiel Euflázio

Administrador, MOS e MOSE em MS Excel, Jardiel é também MCT e desenvolvedor de soluções baseadas na ferramenta. Apaixonado pelo Excel desde cedo, é criador de conteúdo em seu canal de vídeos aberto ao público no YouTube (Jardiel Euflázio - Excel Prime), no qual trata sobre o tema sempre disposto a colaborar com a comunidade.

Excel não precisa ser complicado

Assine nossa newsletter e receba dicas práticas para dominar o excel